Halloween Forum banner
Cancel
Create thread New Forums

My Stranger Things Alphabet Wall

Lighting:
Tags
alphabet arduino netflix stranger things wall
Jump to Latest
20K views 60 replies 19 participants last post by  JeffHaas  
V
#1 ·
Just thought I'd share my version of the Alphabet "Message" Wall from Stranger Things. Finally got it finished! I'm pretty happy with how it came out. It's going to be a lot of fun for the Halloween party! These are WS2811 individually addressable LED's (C9 style bulb cover) controlled by an Arduino Uno. Thanks to Dyne for the guidance on this project.


Image


Image
 
#3 ·
Good job, Vater. It turned out great




At the very least it can be hard coded. It spells out "Hi HF" in the video ('Hi, Halloween Forum"). I'm not sure what the ZE at the end was for, possibly a temporary end-sequence marker, or just the start of some other phrase.


If Vater based the code on the function I described in one of the earlier threads, then it's even more flexible. You could just stuff a phrase into a function like that and it will light up the correct lights, with short random pauses between words/letters.

However, it occurs to me that my code ignored the physical layout of the alphabet wall, as I wrote it with the mindset that the letters would all be in sequential order on the strand. These aren't. For one thing, judging by the plug at the top, these start at the end of the strand rather than the beginning, which makes sense. I also didn't account for any extra lights between lines or between certain letters (P and Q, for example), nor the fact that each line runs in the opposite direction from the previous.

A function consisting of a couple of if-then statements would take care of all of that. You'd supply the current letter as input, and the function would give the LED number as output. Just slice the alphabet up into convenient runs of letters: A-H, I-P, and R-Y and use those (or rather their ascii) in the conditionals. The oddballs, Q and Z, get conditionals as well.

For each group, you'd determine which LED to activate using a different formula. (Note: I habitually call these LEDs "pixels" because I'm used to Adafruit's neopixels.)

Something like this:

Code: 
int chooseLED(char c) {
  if (c >= 65 && c<=72)    // A through H, which are at the end of the strand.
      return numpixels - (c - 65);   // Count from the end of the strand.  Assuming we have the letter D, (c-65) = 3.  
                                     // Assuming 50 pixels (numbered 0 to 49), D would be pixel number 46 (49 - 3)

  else if (c>=73 && c<=80)  // I through P
     return (numpixels - 21) + (c-73);    // numpixels - 21 gives us the position of the LED above I
                                          // then we add (not subtract) the distance to the exact letter from I.

  else if (c>=82 && c<=89)  // R through Y
     return (numpixels - 25) - (c-82);   // numpixels - 25 is R.  Then subtract c-82 to get the distance from R.

  else if (c==81)   // Q
     return numpixels - 12;

  else if (c==90)   // Z
     return numpixels - 34;

  else 
     return 0;   // If this pixel lights up, you know there are extraneous characters.
}
 
V
#6 ·
I was able to pull this off with minimal electronics and coding experience. I'd give this a 6/10 in difficulty level for a beginner. Luckily I had people generous enough to help out with the code.

Here's a list of items needed for this project:

1) DC5V WS2811 LED String lights (strand of 50) -- C9 style bulbs
2) Arduino Uno controller
3) DC 9V power adapter for the Arduino
4) DC 5V adapter to power the lights
5) Female CCTV Power Plug Adapter
6) Male-to-male and male-to-female breadboard jumper cables
7) 300 to 500 Ohm resistor and 1000uf large capacitor (I'm currently not using these but they're recommended)
8) USB printer cable to upload the scripts (also called sketches) from your PC to the Arduino controller
9) Wallpaper or scene setter like the one I used
10) 3M command small hooks (clear plastic)
11) Black acrylic paint
12) Blu-tack, which will probably end up leaving oily spots on the walls :\

See this guide: https://learn.adafruit.com/adafruit-neopixel-uberguide/power

Once I got everything wired up, I downloaded the Arduino software (https://www.arduino.cc/en/Main/Software) to my Windows laptop. Then I installed the FastLED library, which includes a lot of "sketch" code examples to make your LED lights do cool effects. You have to make minor modifications to the code to set the amount of the LED's you have, the data pin you're using on the Arduino, etc.

There's also another version of an Alphabet Wall here with a write-up: https://www.sparkfun.com/news/2181 -- this one has code to allow your message wall to be controlled via twitter when specific hashtags are included.
 
#11 ·
Ah, cool. That getIndex function looks more or less like what I wrote earlier in the thread (though with switch-case statements, which I considered but didn't bother to do, because I constantly forget the syntax). Good to know I wasn't way off base with what I came up with with zero real testing.

As I looked at your function, I initially thought it confirmed that I was returning a few numbers that were off by one. Like where I return 16 (numpixels-34 is 50-34, or 16)** for Z, and you return 17. I'd already suspected that my code might have this issue (due to miscounting LEDs or whatever), and your code obviously worked. Then I thought to look for the function call and saw int i = getIndex(c)-1;

Don't judge me, I just woke up. :)


** I wrote my formulas using a (fake) "number of pixels" variable. The Adafruit library would provide the real thing. I don't know if FastLED does or not. If the real code were written this way then it would automatically account for expanding the LED strand to have more lights (or less, if you removed some of the extras). Maybe the Alphabet wall gets expanded to include punctuation, lowercase letters, numbers, and a couple of space invader sprites in "Stranger Things 2: Stranger Danger"
 
V
#14 ·
Dyne said:
Maybe the Alphabet wall gets expanded to include punctuation, lowercase letters, numbers, and a couple of space invader sprites in "Stranger Things 2: Stranger Danger"
Click to expand...
Lol



I wasn't confident either but I was able to figure it out with Dyne's help and another programmer. I say just buy the items so you can force yourselves to figure this out. It's not that hard, there's still plenty of time, and we'll be here to guide you along the way. Once you get the hang of this project, you're gonna want to start doing all sorts of lighting projects. I plan on using these lights for my Christmas tree in a few months. It's a great investment. :D Eventually I want to create light shows in the front of the house for Halloween and Xmas...like the light shows that you see go viral. Learning this stuff is going to be the basics to going to that level.

Most of the items needed can be found on Amazon.

Start by buying the lights: https://amzn.com/B01DZV3PNO

The Arduino Uno controller: https://amzn.com/B008GRTSV6

--These are the two biggest items to purchase.

The adapter I'm using to power the Arduino: https://amzn.com/B01COVIFYU

The adapter I'm using to power the lights: https://www.altex.com/Switching-Wall-Plug-In-AC-Power-Adapter-5VDC-4A-SPS5DC-4A-P149955.aspx

You can find other items like breadboard jumper cables at an electronics or computer shop. I'll post a picture of my arduino setup so you can see how it's wired up.

Pretty sure I stayed under $100 with everything I bought.

EDIT 10/21: See JeffHass' post here for the most up-to-date code: http://www.halloweenforum.com/hallo....com/halloween-props/152337-my-stranger-things-alphabet-wall-5.html#post2030962
 
V
#17 ·
This project cannot be done with just any set of traditional string incandescent lights. I suppose it's possible but would require a lot of time and hacking. They have to be individually addressable LED's ("pixels"). Google WS2811 or WS2812 string led's. All of the individually addressable strings you'll find these days are LED-based.

Rather than spend $40 for the 50-led string WS2811 lights, this guy chose to do it the hard way for the more realistic vintage look: https://www.youtube.com/watch?v=ZkAxEGFXsic

In my case my party guests wont be able to tell the difference since it'll be dark.
 
#22 ·
Has anyone tried to connect their Arduino to twitter so it can tweet specific hash tags? I read the link posted on page 1 here, but was wondering if anyone has tried it?
All of my parts came in yesterday - excited to get started with my neighbor!

I am thinking I will do the alphabet and lights on insulation foam board so after the party, I can move it where ever I want to have it!
 
V
#23 ·
It doesn't always have to be connected to a laptop. Once you upload the script, the Arduino will hold it in memory. I can make it loop through several different messages by adding multiple lines of the write function in the code. There are also ways to get it working with a 9V battery if you buy the necessary stuff for the arduino so it doesn't have to be plugged in.
 
#25 ·
This is a very cool project. I think that if this was on display at a party or a haunt, I'd like to see the whole sequence run. Right now you've got the startup happening only when it powers up. I changed it to light up the whole strand, flicker, and then show the message. Once that's over, it does it again.

Anytime I've set up an effect like this, people will watch for awhile and then wander off to do other stuff, so I think the whole effect should repeat.

I made a few small tweaks to the Arduino code:

- Moved two of the effects, lighting up the strand and flickering it, into their own functions. This makes the main loop just about controlling everything.
- Added some test lines of text, "abcedfghi" all the way to Z, so you can set up the LEDs and letters on the wall, then un-comment the test lines and see if all the LEDs and letters line up right.
- Added more comments to the code, for people who are getting started out.

Put a space in the message when you want a pause.


Code: 
// Stranger Things Alphabet Wall
// From a Halloween Forum discussion:
// http://www.halloweenforum.com/halloween-props/152337-my-stranger-things-alphabet-wall.html
// Original code by Vater

// The Mokungit RGB addressable LEDs come with 50 pixels in the string, so this code
// has been set up to start the alphabet at the end of the string (pixel #50)
// with the LEDs winding back and forth on the wall.  

// When you have the LEDs and letters on the wall, uncomment the "abcedefgh" 
// and other two messages below to check alignment with the letters.  Then comment
// them back out when you're done.

// Updated 10/4/2016 to move "all on" and "flicker" effects into their own functions.
// This makes timing the entire effect easier, and restarts the whole effect each time
// all the messages have been shown.  Also added test strings of letters.

#include <FastLED.h>
#define DATA_PIN 6    // LED pin.  Change this for your setup if needed.

template<typename T, size_t N> constexpr size_t countof(const T(&)[N]) { return N; }

// Set this to match the number LEDs in the string.  Originally 50.
CRGB leds[50];  

// Only a few colors
CRGB colors[] = {
  0xEEEEEE,
  0xFFDD11,
  0x00BBFF,
  0xFF66FF
};

uint8_t index[countof(leds)];

void setup() {
  for (auto &color : colors) napplyGamma_video(color, 2.2);
  for (auto &i : index) i = random8(countof(colors));
  
  FastLED.addLeds<WS2812B, DATA_PIN, GRB>(leds, countof(leds));
  FastLED.setBrightness(63);
}

// The loop controls the main effect.  Change pauses to get the timing you want.

void loop() {

  LiteUp();     // Light up the strand of LEDs
  delay(5000);  // Wait five seconds 
  Flicker();    // Flicker them
  delay(2000);  // Wait two seconds before the first message is shown
  
//  write("abcdefgh");  // Uncomment these to test your setup
//  write("ijklmnop");
//  write("qrstuvwxyz");

  write("Help me ");   // Change messages in quotes to whatever you want
  write("Im trapped");
  delay(5000);   // Wait five seconds after the last message before it starts again
}

int getIndex(char c) {    
  c = toUpperCase(c);
  switch (c) {
    case 'A'...'H':
      return 50 - (c - 'A');  

    case 'I'...'P':
      return 30 + (c - 'I');  

    case 'Q':     
      return 39;

    case 'R'...'Y':  
      return 26 - (c - 'R');

    case 'Z':   
      return 17;

    default:
      return 0;
  }
}

void write(char c) {
  if (isAlpha(c)) {
    // Get index and convert to 0-based indexing
    int i = getIndex(c)-1;  // (c)-2 gets to first pixel in strand if needed
    
    leds[i] = colors[index[i]];
    FastLED.show();
    delay(750);
    
    leds[i] = CRGB::Black;
    FastLED.show();
    delay(250);
  } else if (isSpace(c)) {
    delay(1000);
  }
}

void write(const char *str) {
  while (*str) write(*str++);
} 

void LiteUp(){        // Turn all on
  for (size_t i = 0; i < countof(leds); i++) leds[i] = colors[index[i]];
  FastLED.show();
}

void Flicker (){      // Flicker the strand

  for (int i = 0; i < 128; i++) {
    if (random8() > ease8InOutQuad(i*2))
      FastLED.show();
    else
      // To prevent having to repopulate leds[], we
      // simply show black instead of clearing the array.
      FastLED.showColor(CRGB::Black);

    delay(33);
  }
  FastLED.clear();
}
 
V
#26 ·
EDIT 10/21: See JeffHass' post here (page 5) for the most up-to-date code: http://www.halloweenforum.com/hallo....com/halloween-props/152337-my-stranger-things-alphabet-wall-5.html#post2030962

JeffHaas said:
This is a very cool project. I think that if this was on display at a party or a haunt, I'd like to see the whole sequence run. Right now you've got the startup happening only when it powers up. I changed it to light up the whole strand, flicker, and then show the message. Once that's over, it does it again.

Anytime I've set up an effect like this, people will watch for awhile and then wander off to do other stuff, so I think the whole effect should repeat.

I made a few small tweaks to the Arduino code:

- Moved two of the effects, lighting up the strand and flickering it, into their own functions. This makes the main loop just about controlling everything.
- Added some test lines of text, "abcedfghi" all the way to Z, so you can set up the LEDs and letters on the wall, then un-comment the test lines and see if all the LEDs and letters line up right.
- Added more comments to the code, for people who are getting started out.

Put a space in the message when you want a pause.
Click to expand...
Awesome, thanks Jeff! You're absolutely right and I have since added changes to make it loop. I would also add that the code randomly assigns colors based on the hex values specified under "CRGB colors[]". The colors currently specified may not look the best, but they are easy to change. Simply edit the hex color codes. For example FFFFFF is white, 0000ff is blue, ff0000 is red, etc. Add "0x" before the hex value. Use this site to pick your colors and determine what the hex val is for each color you choose: http://www.w3schools.com/colors/colors_picker.asp

Here's another good site for picking colors: http://htmlcolorcodes.com/color-picker/

The colors below should give more of a traditional Christmas lights look. Edit to your liking:
//white
0xFFFFFF,
//yellow
0xFFA500,
//blue
0x0000FF,
//aqua
0x00FFFF,
//red
0xFF0000,
//green
0x008000

(Don't add a comma on the last color value)

Credit to DanRoad for the original code.
 
V
#30 ·
Here are some pics of how I have mine wired:

Here's a simple wiring guide and diagram if you plan on wiring the capacitor/resistor: Adafruit NeoPixel Überguide

Be extra careful not to reverse the negative/positive terminals of the capacitor! Don't do this:


summerstark said:
awesome. where did you get the floral wall covering? and did you paint the letters or use a marker?
Click to expand...
I bought this: https://amzn.com/B00BFWCSXE

I just wish it wasn't so glossy/reflective...but it works. I need to look around for cheap floral vintage wallpaper. I painted the letters with a small brush and black acrylic paint I found at Michael's. The advantage to the backdrop being plastic is that I can easily wipe the paint off with a damp paper towel before it dries.
 
S
#31 ·
[




I bought this: https://amzn.com/B00BFWCSXE

I just wish it wasn't so glossy/reflective...but it works. I need to look around for cheap floral vintage wallpaper. I painted the letters with a small brush and black acrylic paint I found at Michael's. The advantage to the backdrop being plastic is that I can easily wipe the paint off with a damp paper towel before it dries.[/QUOTE]

thank you!
 
G
#32 ·
Arduino: 1.6.12 (Windows 10), Board: "Arduino Uno"

WARNING: Category '' in library EEPROM is not valid. Setting to 'Uncategorized'
WARNING: Category '' in library SPI is not valid. Setting to 'Uncategorized'
WARNING: Category '' in library SoftwareSerial is not valid. Setting to 'Uncategorized'
WARNING: Category '' in library Wire is not valid. Setting to 'Uncategorized'
Warning: platform.txt from core 'Arduino AVR Boards' contains deprecated recipe.ar.pattern="{compiler.path}{compiler.ar.cmd}" {compiler.ar.flags} {compiler.ar.extra_flags} "{build.path}/{archive_file}" "{object_file}", automatically converted to recipe.ar.pattern="{compiler.path}{compiler.ar.cmd}" {compiler.ar.flags} {compiler.ar.extra_flags} "{archive_file_path}" "{object_file}". Consider upgrading this core.
In file included from C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino:18:0:

C:\Program Files (x86)\Arduino\libraries\FastLED-master/FastLED.h:17:21: note: #pragma message: FastLED version 3.001.003

# pragma message "FastLED version 3.001.003"

^

strangerthingsdelayadded_oct14a:42: error: array bound is not an integer constant before ']' token

uint8_t index[countof(leds)];

^

C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino: In function 'void setup()':

strangerthingsdelayadded_oct14a:45: error: ISO C++ forbids declaration of 'color' with no type [-fpermissive]

for (auto &color : colors) napplyGamma_video(color, 2.2);

^

strangerthingsdelayadded_oct14a:45: error: range-based 'for' loops are not allowed in C++98 mode

for (auto &color : colors) napplyGamma_video(color, 2.2);

^

strangerthingsdelayadded_oct14a:45: error: no matching function for call to 'napplyGamma_video(int&, double)'

for (auto &color : colors) napplyGamma_video(color, 2.2);

^

C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino:45:58: note: candidates are:

In file included from C:\Program Files (x86)\Arduino\libraries\FastLED-master/FastLED.h:58:0,

from C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino:18:

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1695:8: note: CRGB& napplyGamma_video(CRGB&, float)

CRGB& napplyGamma_video( CRGB& rgb, float gamma);

^

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1695:8: note: no known conversion for argument 1 from 'int' to 'CRGB&'

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1696:8: note: CRGB& napplyGamma_video(CRGB&, float, float, float)

CRGB& napplyGamma_video( CRGB& rgb, float gammaR, float gammaG, float gammaB);

^

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1696:8: note: candidate expects 4 arguments, 2 provided

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1697:8: note: void napplyGamma_video(CRGB*, uint16_t, float)

void napplyGamma_video( CRGB* rgbarray, uint16_t count, float gamma);

^

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1697:8: note: candidate expects 3 arguments, 2 provided

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1698:8: note: void napplyGamma_video(CRGB*, uint16_t, float, float, float)

void napplyGamma_video( CRGB* rgbarray, uint16_t count, float gammaR, float gammaG, float gammaB);

^

C:\Program Files (x86)\Arduino\libraries\FastLED-master/colorutils.h:1698:8: note: candidate expects 5 arguments, 2 provided

strangerthingsdelayadded_oct14a:46: error: ISO C++ forbids declaration of 'i' with no type [-fpermissive]

for (auto &i : index) i = random8(countof(colors));

^

strangerthingsdelayadded_oct14a:46: error: range-based 'for' loops are not allowed in C++98 mode

for (auto &i : index) i = random8(countof(colors));

^

strangerthingsdelayadded_oct14a:46: error: 'index' was not declared in this scope

C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino: In function 'void write(char)':

strangerthingsdelayadded_oct14a:98: error: 'index' was not declared in this scope

leds = colors[index];

^

C:\Users\Anna\Documents\Arduino\strangerthingsdelayadded_oct14a\strangerthingsdelayadded_oct14a.ino: In function 'void LiteUp()':

strangerthingsdelayadded_oct14a:115: error: 'index' was not declared in this scope

for (size_t i = 0; i < countof(leds); i++) leds = colors[index];

^

exit status 1
array bound is not an integer constant before ']' token

This report would have more information with
"Show verbose output during compilation"
option enabled in File -> Preferences.



|| I am getting all these errors. Can anyone help?
 
#34 ·
OK, time for basic troubleshooting...

The first thing you should check is that you have the current version of the Arduino software. At the top lett of the Arduino window is the name of the sketch you're working on and a version number. The current one is 1.6.12.

If you have an older one, go to:
https://www.arduino.cc/
Click Download, and get the current version for your computer and install it.

Once you have the current version of the Arduino software, make sure you have the current version of the FastLed library. Start the Arduino software, then go to this menu (this is on the PC, the Mac may be slightly different):
Sketch > Include Library > Manage Libraries

This pops up a window called "Library Manager". In the top right of this window is a search box, type "Fastled" into it. It should find "FastLed by Daniel Garcia" and a version number. Click on that section and some drop-downs will show up that allow you to pick the current version number, which is 3.1.3, and install it. The Arduino software can download the current version and install it for you (this is sooo much easier than what you used to have to do!)

Once you've done that, then you can try out any of the examples that are installed when you add a library. Go to:
File > Examples
and scroll down. Look for "Examples from custom libraries" (you may need to scroll the menu down a bit) and you should see FastLed, hover over it and a window will pop out to the right with all the demos for that software. Pick one like "Blink", it will load up in a new window. Click the Verify button (the checkmark in a circle in the upper left, just under the File menu) to see if it compiles properly. Tip: You can Verify code without having an Arduino hooked up to your computer.

If that works, then you should be able to open a new window (File > New or CTRL + N), paste in either version of the code in this thread and click the Verify button for it. It should compile properly, and then you're ready to actually load it onto an Arduino.

You will still need to hook up the Neopixel strands properly, give them the right power supply, etc etc as described in the Adafruit guide.
 
V
#35 ·
Good advice there from Jeff. I would use this guide to install FastLED: http://www.instructables.com/id/Import-a-Code-Library-to-Arduino/

If you can successfully run the examples that are included with FastLED, you should be able to get the code we provided working. Go to File > Examples > FastLED > DemoReel100. Then you'll want to edit these lines:

#define DATA_PIN 3 <--- Use the data pin number you connected the LED lights to. In my case I used 6
//#define CLK_PIN 4 <-- not applicable for the lights I bought so it's commented out
#define LED_TYPE WS2811
#define COLOR_ORDER GRB <--- The lights I bought should be RGB and not GRB.
#define NUM_LEDS 64 <--- change this to 50 if you bought the same lights I used
CRGB leds[NUM_LEDS];

Once you've edited these lines, are you able to run DemoReel100?

If you can run the examples fine but not the alphabet wall code, then it would be helpful to see screenshots of your setup and the errors so we can go from there.
 
G
#37 ·
I had the correct version of the Arduino software, but I uninstalled it and reinstalled it again. I installed the library like you said. Then, I ran Blink, ColorPallete, and DemoReel examples and they all worked. However, I am still getting the same errors that I posted above with your code. I am attaching the errors I am getting. I copied and pasted JeffHaas's code.
 
#38 · (Edited)
Thanks for checking that, it helps troubleshoot.

All those errors show that something isn't set up in the code, so I think that cutting and pasting the code from the forum isn't working for you. So I've zipped up the sketch and have attached it here. Try downloading this file, unzipping it, putting the folder with the sketch in your Arduino folder (on my machine, it's in Documents >Arduino), and then restarting the Arduino software. The sketch should be in the Sketchbook menu.

Then try Verifying it and see what happens.

FYI, my set of these Mokungit lights got slowed by the hurricane in Florida and should get here in a day or so. I've been testing using a shorter strand of 30 LEDs, so there's some code that's commented out to deal with that.
 

Attachments

V
#40 ·
First I would try copying the haas_example.ino file inside of the haas_example folder. It appears you have a folder named haas_example.ino then a haas_example.ino file inside of that. Not sure if this would cause issues. Also make sure the file is named haas_example.ino and not haas_example.ino.ino as I'm seeing in your screenshot log. Then try running it again.

Another thing I noticed is before you reinstalled it looks like your FastLED library was located under C:\Program Files (x86)\Arduino\libraries\FastLED-master. Then your code file is located under C:\Users\Anna\Documents\Arduino\. So maybe it was trying to call FastLED.h and is unable to properly call the FastLED library.

I don't have a FastLED-master folder in C:\Program Files (x86)\Arduino\libraries, and based on your log, you do. In my case it's located here: C:\Users\Umbrella\Documents\Arduino\libraries\FastLED-3.1.0

Also I doubt it'd make a difference but I'm running Arduino 1.6.11 and FastLED 3.1.0. Maybe try installing 1.6.11 in case something changed in the new version that is not compatible with the code? Might be worth a shot so we can isolate the problem. You can download this version from here: https://www.arduino.cc/en/Main/OldSoftwareReleases

Seems more like a FastLED problem. it's also possible that something changed in 3.1.3 which is what you're running. You can download 3.1.0 from here: https://github.com/FastLED/FastLED/releases/tag/v3.1.0


C:\Users\Umbrella\Documents\Arduino\libraries\FastLED-3.1.0/FastLED.h:12:2: warning: #warning FastLED version 3.001.000 (Not really a warning, just telling you here.) [-Wcpp]

#warning FastLED version 3.001.000 (Not really a warning, just telling you here.)
 
Halloween Forum
posts
2M
members
89K
Since
2002
Halloween forum - Keeping the Halloween spirit alive 365 days a year. Discuss decorations, costumes and more!
Full Forum Listing
Explore Our Forums
General Halloween Halloween Props Member Introduction Party Ideas. Experiences and Recipes Store Sightings & Group Buys